3dprinting/spoolmount
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

Path reorg

Browse Source
This commit is contained in:
Ian Gulliver
2024-07-12 09:08:58 -07:00
parent a0867baac9
commit dc7d3a9252
27 changed files with 65 additions and 44 deletions
Download Patch File Download Diff File Expand all files Collapse all files

44
v1/scad/lib/generic/extension_clip.scad Normal file
View File

@@ -0,0 +1,44 @@
use <spoolmount_a.scad>
use <spoolmount_b.scad>
module extension_clip(h) {
assert(h >= 14, "minimum extension_clip height is 14");
// Bottom spoolmount
spoolmount_b();
// Top spoolmount
translate([0, 0, h - 5])
spoolmount_a();
translate([0, 0, 4]) {
// Inner center cylinder
difference() {
cylinder(h=h - 8, r=29, $fn=200);
translate([0, 0, -1])
cylinder(h=h - 6, r=25.1, $fn=200);
}
difference() {
cylinder(h=h - 8, r=42, $fn=200);
translate([0, 0, -1])
cylinder(h=h - 6, r=37, $fn=200);
}
}
// Expansion to support top spoolmount
translate([0, 0, h - 9])
rotate_extrude($fn=200)
polygon(points=[
[29, 0],
[29, 5],
[37, 5],
[37, 0],
[33, 4],
[29, 0],
]);
}
extension_clip(h=25);

30
v1/scad/lib/generic/extension_twist.scad Normal file
View File

@@ -0,0 +1,30 @@
use <spoolmount_twist.scad>
module extension_twist(h, twist) {
assert(h >= 10, "minimum extension_twist height is 10");
// Bottom spoolmount twist
spoolmount_twist();
// Top spoolmount twist
translate([0, 0, h])
rotate([180, 0, twist])
spoolmount_twist();
difference() {
union() {
// Outer body cylinder
translate([0, 0, 4.5])
cylinder(h=h - 9, r=25, $fn=200);
// Inner body cylinder
translate([0, 0, 2.5])
cylinder(h=h - 5, r=23, $fn=200);
}
// Inner through cutout
cylinder(h=h, r=16.25, $fn=200);
}
}
extension_twist(h=25, twist=30);

30
v1/scad/lib/generic/ptfe_guide_4.scad Normal file
View File

@@ -0,0 +1,30 @@
use <../util/screw_hole_m3.scad>
module ptfe_guide_4() {
translate([0, 0, 5])
difference() {
hull() {
for (x = [-22, 22]) {
for (y = [-4, 4]) {
for (z = [-3, 3]) {
translate([x, y, z])
sphere(d=4, $fn=100);
}
}
}
}
// Screw hole
translate([0, 0, -5])
screw_hole_m3(h=10);
// PTFE holes
for (x = [-18, -10, 10, 18]) {
translate([x, 0, 0])
rotate([90, 0, 0])
cylinder(h=14, d=4.4, center=true, $fn=100);
}
}
}
ptfe_guide_4();

45
v1/scad/lib/generic/spool_holder_clip.scad Normal file
View File

@@ -0,0 +1,45 @@
use <spoolmount_b.scad>
use <../util/torus.scad>
module spool_holder_clip(h) {
assert(h >= 25, "minimum spool_holder_clip height is 25");
spoolmount_b();
// Fill in spoolmount
cylinder(h=5, r=26);
// Main body
translate([0, 0, 5])
cylinder(h=h - 5, r=12, $fn=200);
// Base fan in
translate([0, 0, 5])
rotate_extrude($fn=200)
translate([12, 0])
difference() {
square(10);
translate([10, 10])
circle(r=10);
}
// Cap
translate([0, 0, h - 5])
cylinder(h=5, r=17, $fn=200);
// Cap fan out
translate([0, 0, h - 10])
rotate_extrude($fn=200)
polygon(points=[
[12, 0],
[17, 5],
[12, 5],
]);
// Cap rounded edge
translate([0, 0, h - 2.5])
torus(r_major=17, r_minor=2.5, xs=0.7, $fn=200);
}
spool_holder_clip(h=100);

42
v1/scad/lib/generic/spool_holder_twist.scad Normal file
View File

@@ -0,0 +1,42 @@
use <spoolmount_twist.scad>
use <../util/torus.scad>
module spool_holder_twist(h) {
assert(h >= 25, "minimum spool_holder_twist height is 25");
spoolmount_twist();
// Main body
translate([0, 0, 5])
cylinder(h=95, r=12, $fn=200);
// Base fan in
translate([0, 0, 5])
rotate_extrude($fn=200)
translate([12, 0])
difference() {
square(10);
translate([10, 10])
circle(r=10);
}
// Cap
translate([0, 0, h - 5])
cylinder(h=5, r=17, $fn=200);
// Cap fan out
translate([0, 0, h - 10])
rotate_extrude($fn=200)
polygon(points=[
[12, 0],
[17, 5],
[12, 5],
]);
// Cap rounded edge
translate([0, 0, h - 2.5])
torus(r_major=17, r_minor=2.5, xs=0.7, $fn=200);
}
spool_holder_twist(h=100);

64
v1/scad/lib/generic/spoolmount.scad Normal file
View File

@@ -0,0 +1,64 @@
use <../util/torus.scad>
module spoolmount() {
// Ring
difference() {
// Cylinder body
cylinder(h=5, r=42, $fn=200);
// Central through hole
cylinder(h=5, r=25.1, $fn=200);
// Bottom slightly wider cutout
translate([0, 0, -1])
cylinder(h=1.5, r=25.45, $fn=200);
// Top slightly wider cutout
translate([0, 0, 4.5])
cylinder(h=1.5, r=25.45, $fn=200);
}
for (a = [45 : 90 : 335]) {
// Locking bumps
rotate([0, 0, a - 10])
rotate_extrude(angle=20, $fn=200)
translate([23.1, 0, 0])
polygon(points=[
[2.0, 0],
[2.0, 0.5],
[0, 2.5],
[2.0, 4.5],
[2.0, 5],
]);
// Rounded bump ends
for (o = [-10, 10]) {
rotate([0, 0, a + o])
translate([0, 30.1, 0])
scale([0.2, 1.0, 1.0])
rotate_extrude($fn=200)
translate([5, 0, 0])
polygon(points=[
[0, 0.5],
[2.0, 2.5],
[0, 4.5],
]);
}
}
// Rounded outer edge
translate([0, 0, 2.5]) {
torus(r_major=42, r_minor=2.5, xs=0.7, $fn=200);
}
// Rounded inner edges
{
translate([0, 0, 0.5])
torus(r_major=25.45, r_minor=0.5, xs=0.7, $fn=200);
translate([0, 0, 4.5])
torus(r_major=25.45, r_minor=0.5, xs=0.7, $fn=200);
}
}
spoolmount();

42
v1/scad/lib/generic/spoolmount_a.scad Normal file
View File

@@ -0,0 +1,42 @@
use <spoolmount.scad>
// SpoolMount fixed side (i.e. attached to printer or enclosure)
module spoolmount_a() {
spoolmount();
// Hooks
for (x = [-33, 33]) {
translate([x, 0, 5])
rotate([0, -90, 0])
linear_extrude(6, center=true) {
polygon(points=[
[0, 0],
[0, 4],
[2, 4],
[4, 6],
[5, 6],
[5, 2],
[3, 0],
[0, 0],
]);
translate([3, 2])
circle(r=2, $fn=50);
}
}
// Locking bump
translate([0, -30.8, 5])
rotate([0, -90, 0])
linear_extrude(6, center=true) {
polygon(points=[
[0, 0],
[1.6, -4],
[1.6, -5],
[0, -5],
[0, 0],
]);
}
}
spoolmount_a();

29
v1/scad/lib/generic/spoolmount_b.scad Normal file
View File

@@ -0,0 +1,29 @@
use <spoolmount.scad>
// SpoolMount removable side (i.e. attached to spool holder or cage)
module spoolmount_b() {
difference() {
spoolmount();
// Holes
for (a = [0 : 30 : 330]) {
rotate([0, 0, a])
translate([29.75, 0, 0]) {
// Center through hole
translate([3.25, 0, 3])
cube([6.5, 8, 7], center=true);
// Diagonal sides
translate([3.25, 0, 4])
rotate([45, 0, 0])
cube([6.5, sqrt(72), sqrt(72)], center=true);
// Flat top cutout
translate([3.25, 0, 5])
cube([6.5, 12, 2], center=true);
}
}
}
}
spoolmount_b();

107
v1/scad/lib/generic/spoolmount_twist.scad Normal file
View File

@@ -0,0 +1,107 @@
use <../util/torus.scad>
module spoolmount_twist() {
difference() {
union() {
difference() {
union() {
// Core cylinder body
translate([0, 0, 0.5])
cylinder(h=4, r=25, $fn=200);
// Slightly narrower bottom/top body
cylinder(h=5, r=24.65, $fn=200);
// Bottom outer rounded edge
intersection() {
cylinder(h=0.5, r=25, $fn=200);
translate([0, 0, 0.5])
torus(r_major=24.65, r_minor=0.5, xs=0.7, $fn=200);
}
// Top outer rounded edge
intersection() {
translate([0, 0, 4.5])
cylinder(h=0.5, r=25, $fn=200);
translate([0, 0, 4.5])
torus(r_major=24.65, r_minor=0.5, xs=0.7, $fn=200);
}
}
for (a = [45 : 90 : 335]) {
// Slide bump entrance cutout
rotate([0, 0, a - 13])
rotate_extrude(angle=26, $fn=200)
translate([23, 0, 0])
polygon(points=[
[0, -1],
[3, -1],
[3, 2.5],
[0, 2.5],
]);
// Slide cutout
rotate([0, 0, a - 40])
rotate_extrude(angle=80, $fn=200)
translate([23, 0, 0])
polygon(points=[
[3, 0.5],
[2, 0.5],
[0, 2.5],
[2, 4.5],
[3, 4.5],
]);
}
// Inner cutout
translate([0, 0, -1])
cylinder(h=7, r=18, $fn=200);
}
// Locking bumps
intersection() {
translate([0, 0, 0.5])
cylinder(h=4, r=25, $fn=200);
for (a = [45 : 90 : 335]) {
for (o = [-19.15, 19.15]) {
rotate([0, 0, a + o])
translate([0, 23.9, 0]) {
translate([0, 0, 1])
rotate([45, 0, 0])
cylinder(h=3.5, d=1.1, center=true, $fn=50);
translate([0, 0, 4])
rotate([-45, 0, 0])
cylinder(h=3.5, d=1.1, center=true, $fn=50);
}
}
}
}
}
// Rounded cutouts
for (a = [45 : 90 : 335]) {
for (o = [-40, -20, 20, 40]) {
rotate([0, 0, a + o])
translate([0, 30.5, 0])
scale([0.2, 1.0, 1.0])
rotate_extrude($fn=200)
translate([5, 0, 0])
polygon(points=[
[0, 0],
[2.5, 2.5],
[0, 5],
]);
}
}
}
// Inner rounded edge
translate([0, 0, 2.5])
torus(r_major=18, r_minor=2.5, xs=0.7, $fn=200);
}
spoolmount_twist();