3dprinting/spoolmount
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

Create v1, scad, objects hierarchy

Browse Source
This commit is contained in:
Ian Gulliver
2024-07-11 09:16:54 -07:00
parent 1537b8bd1b
commit 05bbf5b8fa
20 changed files with 16 additions and 16 deletions
Download Patch File Download Diff File Expand all files Collapse all files

27
v1/scad/lib/extension.scad Normal file
View File

@@ -0,0 +1,27 @@
use <spoolmount_a.scad>
use <spoolmount_b.scad>
module extension(h) {
assert(h >= 23, "minimum extension height is 23");
// Bottom spoolmount
spoolmount_b();
// Top spoolmount
translate([0, 0, h - 5])
spoolmount_a();
// Center cylinder
cylinder(h=h, r=29, $fn=200);
// Expansion to support top spoolmount
translate([0, 0, h - 18])
rotate_extrude($fn=200)
polygon(points=[
[29, 0],
[42, 13],
[29, 13],
]);
}
extension(h=25);

30
v1/scad/lib/extension_twist.scad Normal file
View File

@@ -0,0 +1,30 @@
use <spoolmount_twist.scad>
module extension_twist(h, twist) {
assert(h >= 10, "minimum extension height is 10");
// Bottom spoolmount twist
spoolmount_twist();
// Top spoolmount twist
translate([0, 0, h])
rotate([180, 0, twist])
spoolmount_twist();
difference() {
union() {
// Outer body cylinder
translate([0, 0, 4.5])
cylinder(h=h - 9, r=25, $fn=200);
// Inner body cylinder
translate([0, 0, 2.5])
cylinder(h=h - 5, r=23, $fn=200);
}
// Inner through cutout
cylinder(h=h, r=16.25, $fn=200);
}
}
extension_twist(h=25, twist=30);

120
v1/scad/lib/prusa_enclosure_mount.scad Normal file
View File

@@ -0,0 +1,120 @@
use <spoolmount_a.scad>
use <torus.scad>
module prusa_enclosure_mount(angle) {
translate([0, 0, 13])
spoolmount_a();
rotate([0, 0, angle])
difference() {
union() {
for (yo = [-20, 20]) {
translate([0, yo, 0])
difference() {
// Side body
hull() {
for (x = [30, 127]) {
for (y = [-7, 7]) {
for (z = [2.5, 15.5]) {
translate([x, y, z])
scale([0.7, 0.7, 1.0])
sphere(d=5, $fn=50);
}
}
}
}
// Through screw hole
translate([120, 0, -1])
cylinder(h=20, d=3.2, $fn=50);
// Hex nut / screw head cutout
translate([120, 0, 18 - (2.6 / 2)])
linear_extrude(2.61, center=true)
polygon(points=[
[-2.8, 1.6175],
[0, 3.235],
[2.8, 1.6175],
[2.8, -1.6175],
[0, -3.235],
[-2.8, -1.6175],
]);
// Underside washer alignment cutouts
for (y = [-4, 4]) {
translate([124, y, 0])
cube([2, 2, 2], center=true);
}
}
}
// Center body
hull() {
for (x = [30, 115]) {
for (y = [-25, 25]) {
for (z = [2.5, 15.5]) {
translate([x, y, z])
scale([0.7, 0.7, 1.0])
sphere(d=5, $fn=50);
}
}
}
}
// Spoolmount support ring
{
// Outer core
difference() {
union() {
// Top core
translate([0, 0, 2.5])
cylinder(h=15.5, r=42, $fn=200);
// Bottom core
cylinder(h=18, r=40.25, $fn=200);
}
// Center through cutout
translate([0, 0, -1])
cylinder(h=20, r=25, $fn=200);
// Bottom cutout
translate([0, 0, -1])
cylinder(h=3.5, r=26.75, $fn=200);
}
// Outer bottom rounded edge
translate([0, 0, 2.5])
torus(r_major=40.25, r_minor=2.5, xs=0.7, $fn=200);
// Inner bottom rounded edge
translate([0, 0, 2.5])
torus(r_major=26.75, r_minor=2.5, xs=0.7, $fn=200);
}
}
// Weight reduction holes rows 1/5
for (x = [44.5 : 12 : 105]) {
for (y = [-20 : 40 : 20]) {
translate([x, y, -1])
cylinder(h=20, d=9, $fn=50);
}
}
// Weight reduction holes rows 2/4
for (x = [51 : 12 : 105]) {
for (y = [-10 : 20 : 10]) {
translate([x, y, -1])
cylinder(h=20, d=9, $fn=50);
}
}
// Weight reduction holes row 3
for (x = [56.5 : 12 : 105]) {
translate([x, 0, -1])
cylinder(h=20, d=9, $fn=50);
}
}
}
prusa_enclosure_mount(angle=0);

64
v1/scad/lib/spoolmount.scad Normal file
View File

@@ -0,0 +1,64 @@
use <torus.scad>
module spoolmount() {
// Ring
difference() {
// Cylinder body
cylinder(h=5, r=42, $fn=200);
// Central through hole
cylinder(h=5, r=25.1, $fn=200);
// Bottom slightly wider cutout
translate([0, 0, -1])
cylinder(h=1.5, r=25.45, $fn=200);
// Top slightly wider cutout
translate([0, 0, 4.5])
cylinder(h=1.5, r=25.45, $fn=200);
}
for (a = [45 : 90 : 335]) {
// Locking bumps
rotate([0, 0, a - 10])
rotate_extrude(angle=20, $fn=200)
translate([23.1, 0, 0])
polygon(points=[
[2.0, 0],
[2.0, 0.5],
[0, 2.5],
[2.0, 4.5],
[2.0, 5],
]);
// Rounded bump ends
for (o = [-10, 10]) {
rotate([0, 0, a + o])
translate([0, 30.1, 0])
scale([0.2, 1.0, 1.0])
rotate_extrude($fn=200)
translate([5, 0, 0])
polygon(points=[
[0, 0.5],
[2.0, 2.5],
[0, 4.5],
]);
}
}
// Rounded outer edge
translate([0, 0, 2.5]) {
torus(r_major=42, r_minor=2.5, xs=0.7, $fn=200);
}
// Rounded inner edges
{
translate([0, 0, 0.5])
torus(r_major=25.45, r_minor=0.5, xs=0.7, $fn=200);
translate([0, 0, 4.5])
torus(r_major=25.45, r_minor=0.5, xs=0.7, $fn=200);
}
}
spoolmount();

42
v1/scad/lib/spoolmount_a.scad Normal file
View File

@@ -0,0 +1,42 @@
use <spoolmount.scad>
// SpoolMount fixed side (i.e. attached to printer or enclosure)
module spoolmount_a() {
spoolmount();
// Hooks
for (x = [-33, 33]) {
translate([x, 0, 5])
rotate([0, -90, 0])
linear_extrude(6, center=true) {
polygon(points=[
[0, 0],
[0, 4],
[2, 4],
[4, 6],
[5, 6],
[5, 2],
[3, 0],
[0, 0],
]);
translate([3, 2])
circle(r=2, $fn=50);
}
}
// Locking bump
translate([0, -30.8, 5])
rotate([0, -90, 0])
linear_extrude(6, center=true) {
polygon(points=[
[0, 0],
[1.6, -4],
[1.6, -5],
[0, -5],
[0, 0],
]);
}
}
spoolmount_a();

29
v1/scad/lib/spoolmount_b.scad Normal file
View File

@@ -0,0 +1,29 @@
use <spoolmount.scad>
// SpoolMount removable side (i.e. attached to spool holder or cage)
module spoolmount_b() {
difference() {
spoolmount();
// Holes
for (a = [0 : 30 : 330]) {
rotate([0, 0, a])
translate([29.75, 0, 0]) {
// Center through hole
translate([3.25, 0, 3])
cube([6.5, 8, 7], center=true);
// Diagonal sides
translate([3.25, 0, 4])
rotate([45, 0, 0])
cube([6.5, sqrt(72), sqrt(72)], center=true);
// Flat top cutout
translate([3.25, 0, 5])
cube([6.5, 12, 2], center=true);
}
}
}
}
spoolmount_b();

107
v1/scad/lib/spoolmount_twist.scad Normal file
View File

@@ -0,0 +1,107 @@
use <torus.scad>
module spoolmount_twist() {
difference() {
union() {
difference() {
union() {
// Core cylinder body
translate([0, 0, 0.5])
cylinder(h=4, r=25, $fn=200);
// Slightly narrower bottom/top body
cylinder(h=5, r=24.65, $fn=200);
// Bottom outer rounded edge
intersection() {
cylinder(h=0.5, r=25, $fn=200);
translate([0, 0, 0.5])
torus(r_major=24.65, r_minor=0.5, xs=0.7, $fn=200);
}
// Top outer rounded edge
intersection() {
translate([0, 0, 4.5])
cylinder(h=0.5, r=25, $fn=200);
translate([0, 0, 4.5])
torus(r_major=24.65, r_minor=0.5, xs=0.7, $fn=200);
}
}
for (a = [45 : 90 : 335]) {
// Slide bump entrance cutout
rotate([0, 0, a - 13])
rotate_extrude(angle=26, $fn=200)
translate([23, 0, 0])
polygon(points=[
[0, -1],
[3, -1],
[3, 2.5],
[0, 2.5],
]);
// Slide cutout
rotate([0, 0, a - 40])
rotate_extrude(angle=80, $fn=200)
translate([23, 0, 0])
polygon(points=[
[3, 0.5],
[2, 0.5],
[0, 2.5],
[2, 4.5],
[3, 4.5],
]);
}
// Inner cutout
translate([0, 0, -1])
cylinder(h=7, r=18, $fn=200);
}
// Locking bumps
intersection() {
translate([0, 0, 0.5])
cylinder(h=4, r=25, $fn=200);
for (a = [45 : 90 : 335]) {
for (o = [-19.15, 19.15]) {
rotate([0, 0, a + o])
translate([0, 23.9, 0]) {
translate([0, 0, 1])
rotate([45, 0, 0])
cylinder(h=3.5, d=1.1, center=true, $fn=50);
translate([0, 0, 4])
rotate([-45, 0, 0])
cylinder(h=3.5, d=1.1, center=true, $fn=50);
}
}
}
}
}
// Rounded cutouts
for (a = [45 : 90 : 335]) {
for (o = [-40, -20, 20, 40]) {
rotate([0, 0, a + o])
translate([0, 30.5, 0])
scale([0.2, 1.0, 1.0])
rotate_extrude($fn=200)
translate([5, 0, 0])
polygon(points=[
[0, 0],
[2.5, 2.5],
[0, 5],
]);
}
}
}
// Inner rounded edge
translate([0, 0, 2.5])
torus(r_major=18, r_minor=2.5, xs=0.7, $fn=200);
}
spoolmount_twist();

6
v1/scad/lib/torus.scad Normal file
View File

@@ -0,0 +1,6 @@
module torus(r_major, r_minor, xs=1.0, ys=1.0) {
rotate_extrude()
translate([r_major, 0, 0])
scale([xs, ys, 1.0])
circle(r=r_minor);
}